home *** CD-ROM | disk | FTP | other *** search
/ Shareware Grab Bag / Shareware Grab Bag.iso / 003 / dbapg.arc / CROSSREF.PRG < prev    next >
Encoding:
Text File  |  1984-08-26  |  8.4 KB  |  305 lines
  1. * Program.: CROSSREF.PRG
  2. * Author..: Roy M. Moore, modified by Luis A. Castro
  3. * Date....: 11/1/83, 08/26/84
  4. * Notice..: Copyright 1983, Roy M. Moore, All Rights Reserved.
  5. * Version.: dBASE II, version 2.4x
  6. * Notes...: Creates a reference table of variables for up to
  7. *           30 command files.  
  8. *
  9. CLEAR
  10. SET TALK OFF
  11. SET RAW ON
  12. STORE "PRG" TO extension
  13. *
  14. ERASE
  15. @ 2, 0 SAY "GENERATE CROSS-REFERENCE TABLE"
  16. @ 2,72 SAY DATE()
  17. @ 3, 0 SAY "========================================"
  18. @ 3,40 SAY "========================================" 
  19. ACCEPT "Enter output filename " TO outfile
  20. ? "Enter command filename(s) [separated by commas] "
  21. ACCEPT TO mfiles
  22. STORE "N" TO listit
  23. @ 9, 0 SAY "Print command files? [Y/N] ";
  24.        GET listit PICTURE "!"
  25. READ 
  26. *
  27. * ---Separate list of files.
  28. STORE '11' TO item
  29. DO WHILE ',' $ mfiles
  30.    STORE $( mfiles, 1, @(',',mfiles) - 1 ) TO filename&item
  31.    STORE $( mfiles, @(',',mfiles) + 1 ) TO mfiles
  32.    STORE STR( VAL( item ) + 1, 2 ) TO item
  33. ENDDO
  34. STORE mfiles TO filename&item
  35. STORE item TO item:max
  36. *
  37. * ---Check to see if command file(s) exist.
  38. DO WHILE item >= "11"
  39.    STORE !( TRIM( filename&item ) ) + "." TO filename&item
  40.    STORE $( filename&item, 1,;
  41.          @(".",filename&item) - 1 ) TO filename&item
  42.    IF .NOT. FILE( filename&item + "." + extension )
  43.       ? "&filename&item" + " DOES NOT EXIST"
  44.       CLEAR
  45.       RETURN
  46.    ENDIF
  47.    STORE STR( VAL( item ) - 1, 2 ) TO item
  48. ENDDO
  49. *
  50. * ---The following is a list of the dBASE II "reserved" words. 
  51. * ---Feel free to add or delete what you wish.
  52. *
  53. STORE ",*,AND,USE,WAIT,TO,SET,SKIP,NOT,OR,?," +;
  54.    "ACCEPT,ALL,APPEND,READ,ON,SAY,BELL,BLANK,WHILE," +;
  55.    "BOTTOM,WITH,CASE,CHR,CLEAR," TO tokens1
  56. STORE tokens1 +;
  57.    "COMMAND,CONFIRM,CONSOLE,CONTINUE,COPY,COUNT,CREATE," +;
  58.    "DATE,DELETE,DELIMITED,DISPLAY,DO,EDIT,EJECT,ELSE," +;
  59.    "ENDCASE,ENDDO," TO tokens1
  60. *
  61. STORE ",ENDIF,ENDTEXT,EOF,ERASE,ESCAPE,EXCEPT,EXTENDED," +;
  62.    "FIELD,FILE,FILES,FIND,FOR,ADD,,FORM,FORMAT,FROM,GET," +;
  63.    "GETS,GO,GOTO,HEADING,IF,INDEX," TO tokens2
  64. STORE tokens2 +;
  65.    "INPUT,INSERT,INT,INTENSITY,JOIN,LEN,LIKE,LINKAGE," +;
  66.    "LIST,LOAD,LOCATE,LOOP,MARGIN,MEMORY,MODIFY,NOTE,OFF," +;
  67.    "OTHERWISE," TO tokens2
  68. *
  69. STORE ",PACK,PEEK,PICTURE,POKE,PRIMARY,PRINT,QUIT,RAW," +;
  70.    "BEFORE,RECALL,RECORD,RELEASE,REMARK,RENAME,REPLACE," +;
  71.    "REPORT,RESET,RESTORE,RETURN," TO tokens3
  72. STORE tokens3 +;
  73.    "SAVE,SCREEN,SDF,SECONDARY,SELECT,SORT,STATUS,"+;
  74.    "STORE,STR,STRUCTURE,SUM,TALK,TEST,TEXT,TOP,TOTAL," +;
  75.    "TRIM,TYPE," TO tokens3
  76. *
  77. STORE ",ALTERNATE,UPDATE,VAL,CALL,DESCENDING,ADDITIVE,"+;
  78.       "ASCENDING,EXACT,CANCEL,CHANGE,COLON," TO tokens4
  79. *
  80. * ---Setup the CROSSREF files.
  81. SELECT PRIMARY
  82. USE Crossget
  83. COPY STRUCTURE TO Crossget.$$$
  84. USE Crossget.$$$
  85. *
  86. SELECT SECONDARY
  87. USE Crossput
  88. COPY STRUCTURE TO Crossput.$$$
  89. USE Crossput.$$$
  90. INDEX ON PUT:token + PUT:file TO Crossput
  91. *
  92. SELECT PRIMARY
  93. SET ALTERNATE TO &outfile
  94. *
  95. * ---Now, let's start generating the cross-reference table.
  96. @ 10,0 SAY " "
  97. STORE item:max TO item
  98. *
  99. DO WHILE item >= "11"
  100. *
  101. STORE filename&item + "." + extension TO mfile
  102. ?
  103. ? "Appending command file " + mfile + "... "
  104. APPEND FROM &mfile SDF
  105. GO TOP
  106. IF listit = "Y"
  107.    ? "Printing command file to " + outfile + "..."
  108.    SET ALTERNATE ON
  109.    SET CONSOLE OFF
  110.    ?
  111.    ? "Filename: " + filename&item
  112.    ?
  113.    LIST
  114.    ?
  115.    ? ".PA"
  116.    SET CONSOLE ON
  117.    SET ALTERNATE OFF
  118.    GO TOP
  119. ENDIF
  120. * 
  121. * ---Process the command lines.
  122. ?
  123. ? "Getting the variable names... "
  124. ?
  125. DO WHILE .NOT. EOF
  126.    *
  127.    STORE TRIM( GET:line ) TO workline
  128.    IF workline = " " .AND. LEN( workline ) = 1
  129.       * ---It must be a blank line.
  130.       SKIP
  131.       LOOP
  132.    ENDIF
  133.    *
  134.    * ---Strip leading control characters and blanks.
  135.    STORE 1 TO ptr
  136.    STORE LEN( workline ) TO line:len
  137.    DO WHILE RANK( $(workline,ptr,1) ) < 33 .AND. ptr < line:len
  138.       STORE ptr + 1 TO ptr
  139.    ENDDO
  140.    STORE $( workline, ptr ) TO workline
  141.    *
  142.    * ---Ignore comment lines.
  143.    IF workline = "*"
  144.       SKIP
  145.       LOOP
  146.    ENDIF
  147.    *
  148.    STORE !( workline ) + " " TO workline
  149.    STORE STR( #, 5 ) TO linenumber
  150.    *
  151.    * ---NOTE: This section of dBASE II code can be
  152.    * ---rewritten in assembly code for faster execution.
  153.    *
  154.    * ---Parse a single command line, until end-of-string.
  155.    STORE 1 TO ptr, lastptr
  156.    STORE LEN( workline ) TO line:len
  157.    *
  158.    DO WHILE lastptr <= line:len
  159.    *
  160.    * ---Skip everything but string delimiters ( " ' [ )
  161.    * ---and alpha characters.
  162.    STORE lastptr TO ptr
  163.    STORE RANK( $( workline, ptr, 1 ) ) TO num
  164.    DO WHILE num <> 34 .AND. num <> 39 .AND. num <> 91 .AND.;
  165.             ( num < 65 .OR. num > 90 ) .AND. ptr <= line:len
  166.       STORE ptr + 1 TO ptr
  167.       IF ptr <= line:len
  168.          STORE RANK( $( workline, ptr, 1 ) ) TO num
  169.       ENDIF
  170.    ENDDO
  171.    STORE ptr TO startptr, lastptr
  172.    IF ptr > line:len   
  173.       LOOP
  174.    ENDIF
  175.    * ---Locate a token in the line.
  176.    DO CASE
  177.       CASE num > 64 .AND. num < 91
  178.       * ---Alpha characters.
  179.          DO WHILE ptr <= line:len .AND.;
  180.             ((num>64 .AND. num<91) .OR. (num>47 .AND. num<59))
  181.             STORE ptr + 1 TO ptr
  182.             IF ptr <= line:len
  183.                STORE RANK( $( workline, ptr, 1 ) ) TO num
  184.             ENDIF
  185.          ENDDO
  186.       CASE num = 34 .OR. num = 39 .OR. num = 91
  187.       * ---Literal string.  
  188.          IF num = 91
  189.             STORE 93 TO num
  190.          ENDIF
  191.          STORE @( CHR(num), $( workline, ptr + 1 ) ) TO pos
  192.          IF pos = 0
  193.             * ---Could not find matching string delimiter.
  194.             STORE line:len + 1 TO ptr, lastptr
  195.             LOOP
  196.          ENDIF
  197.          STORE ptr + pos + 1 TO ptr, lastptr
  198.          LOOP
  199.    ENDCASE
  200.    STORE ptr TO lastptr
  201.    *
  202.    * ---END-OF-NOTE: Rewrite in assembly code up to this point.
  203.    *
  204.    STORE $( workline, startptr, lastptr - startptr ) TO token
  205.    STORE "," + token + "," TO token1
  206.    *
  207.    * ---If reserved word then get next token. 
  208.    * ---DO CASE is used instead of IF...ENDIF to reduce 
  209.    * ---the amount of code executed if a match is found.
  210.    DO CASE
  211.       CASE token1 $ tokens1
  212.            LOOP
  213.       CASE token1 $ tokens2
  214.            LOOP
  215.       CASE token1 $ tokens3
  216.            LOOP
  217.       CASE token1 $ tokens4
  218.            LOOP
  219.    ENDCASE
  220.    ?? token + ","
  221.    *
  222.    * ---Check to see if token is already in the CROSSPUT table: 
  223.    STORE $( token + "          ", 1, 10 ) +;
  224.          $( filename&item + "        ", 1, 8 ) TO key:value
  225.    SELECT SECONDARY
  226.    FIND "&key:value"
  227.    *
  228.    IF # = 0
  229.       * ---Token is not in the reference table.
  230.       * ---Create a record for the new token.
  231.       APPEND BLANK
  232.       REPLACE PUT:token WITH token,;
  233.               PUT:file  WITH filename&item,;
  234.               PUT:line  WITH linenumber
  235.    ELSE
  236.       * ---Token is already in the reference table.
  237.       * ---Just add the command line number.
  238.          REPLACE PUT:line WITH TRIM( PUT:line ) + linenumber
  239.    ENDIF
  240.    *
  241.    ENDDO
  242.    SELECT PRIMARY
  243.    SKIP
  244. ENDDO
  245. *
  246. * ---Initialize for the next command file.
  247. STORE STR( VAL( item ) - 1, 2 ) TO item
  248. USE Crossget
  249. COPY STRUCTURE TO Crossget.$$$
  250. USE Crossget.$$$
  251. *
  252. ENDDO
  253. *
  254. * ---Print cross-reference table from CROSSPUT.$$$ 
  255. ?
  256. ? "Printing cross-reference table... "
  257. SET CONSOLE OFF
  258. SET ALTERNATE ON
  259. ?
  260. ? "VARIABLE    FILENAME  OCCURRENCES"
  261. ? "==========  ========  ====================="
  262. *
  263. SELECT SECONDARY
  264. GO TOP
  265. * ---The constant "work:width" should be a multiple of five.
  266. STORE 50 TO work:width
  267. STORE " " TO last:token
  268. DO WHILE .NOT. EOF
  269.    IF PUT:token <> last:token
  270.       ? PUT:token + "  "
  271.       ?? PUT:file + "  "
  272.    ELSE
  273.       ? $( STR( 0, 13 ), 1, 12 ) + PUT:file + "  "
  274.    ENDIF
  275.    ?? $( PUT:line, 1, work:width )
  276.    *
  277.    * ---Print the occurrence lines that follow.
  278.    STORE work:width + 1 TO work:count
  279.    DO WHILE work:count < 250
  280.       IF LEN( TRIM ( $( PUT:line, work:count ) ) ) > 1
  281.          ? $( STR( 0, 23 ), 1, 22 ) +;
  282.            $( PUT:line, work:count, work:width )
  283.       ENDIF
  284.       STORE work:count + work:width TO work:count
  285.    ENDDO
  286.    *
  287.    STORE PUT:token TO last:token
  288.    SKIP
  289. ENDDO
  290. ?
  291. SET ALTERNATE OFF
  292. SET ALTERNATE TO
  293. SET CONSOLE ON
  294. CLEAR
  295. DELETE FILE Crossget.$$$
  296. DELETE FILE Crossput.$$$
  297. DELETE FILE Crossput.ndx
  298. ?
  299. ? "Finished..."
  300. *
  301. SET RAW OFF
  302. SET TALK ON
  303. RETURN
  304. * EOF: CROSSREF.PRG
  305.